Как перенести данные столбцов в строки (с помощью awk)?

У меня есть файл, как это:

n A B C D 
1 01 02 01 01
2 02 02 01 01

и я хочу передать столбцы по строкам, поэтому вывод должен быть таким:

n 1 2
A 01 02
B 02 02
C 01 01 
D 01 01

Я написал эту команду:

awk '{ for (i=1;i<=NF;i++ ) printf $i " " }' file.txt > out-file.txt

проблема в том, что эта команда помещает все в одну строку! поэтому вывод выглядит так:

n 1 2 A 01 02 B 02 02 C 01 01 D 01 01
 Nicolas Martin02 мар. 2012 г., 15:23

Ответы на вопрос(5)

Решение Вопроса

Это может сработать:

awk '{
       for (f = 1; f <= NF; f++) { a[NR, f] = $f } 
     }
     NF > nf { nf = NF }
     END {
       for (f = 1; f <= nf; f++) {
           for (r = 1; r <= NR; r++) {
               printf a[r, f] (r==NR ? RS : FS)
           }
       }
    }' YOURINPUT

Вижу этов действии @ Ideone.

Ну, без awk мы можем сделать это сcat:

for x in `cat filename`
do
echo $x
done

С помощью этого скрипта результат будет отображаться в столбцах.

 Hello7128 авг. 2014 г., 01:24
это не решает вопрос.

Было бы проще в использованииrs:

$ cat /tmp/a
n A B C D
1 01 02 01 01
2 02 02 01 01
$ rs -c' ' -C' ' -T</tmp/a
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

-c изменяет разделитель входных столбцов,-C изменяет разделитель выходного столбца и-T транспонирует строки и столбцы.

{ for (i=1; i<=NF; i++) col[i] = col[i] " " $i }
END { 
    for (i=1; i<=NF; i++) { 
        sub(/^ /, "", col[i]); 
        print col[i] 
    } 
}
обсуждениеЭто решение использует одномерный массивседло, в котором хранится значение для всего столбца.Col [1] это первый столбец.Для каждой строки мы добавляем столбец к col [i]. Потому что мы слепо добавляем,Col [я] значение будет содержать начальный пробел.В конце функция sub () удаляет начальный пробел перед печатью столбца (теперь строка)

Сохраните этот скрипт как transpose.awk иchmod u+x transpose.awk, Это модификацияТима шервуда transpose.

#!/usr/bin/gawk -f

BEGIN {
    max_x =0;
    max_y =0;
}

{
    max_y++;
    for( i=1; i<=NF; i++ )
    {
        if (i>max_x) max_x=i;
        A[i,max_y] = $i;
    }
}

END {
    for ( x=1; x<=max_x; x++ )
    {
        for ( y=1; y<=max_y; y++ )
        {
            if ( (x,y) in A ) printf "%s",A[x,y];
            if ( y!=max_y ) printf " ";
        }
        printf "\n";
    }
}

Пример:

$ ./transpose.awk example
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01
 Nicolas Martin02 мар. 2012 г., 15:31
Спасибо за ссылку. Он полон замечательных сценариев!

Ваш ответ на вопрос