Агрегат-функция для суммы и произведения в XPath

Аналогично этому вопросу (http://stackoverflow.com/q/1333558/948404) Я хочу использовать XPath для расчета суммы по продуктам в такой структуре:

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

Есть ли выражение XPath, которое вычисляет сумму произведений каждого элементаvalue а такжеquantity?

Update: Решение должно работать с классом PHPs XSLTProcessor, что означает, что оно, вероятно, должно быть совместимо с XSLT 1.0. Вот почему я еще не принял два, вероятно, правильных ответа, используя XSLT 2.0. Я не смог проверить их ни в своей реализации PHP, ни в своем браузере, ни в редакторе Tryit [1] из w3schools. Сожалею!

http://w3schools.com/xsl/tryxslt.asp?xmlfile=cdcatalog&xsltfile=cdcatalog
 PeerBr04 нояб. 2014 г., 14:57

Ответы на вопрос(3)

На основании этого предложенияhttps: //stackoverflow.com/a/1334165/94840 Я предложил решение, совместимое с XSLT 1.0 и XPath 1.0, которые реализованы в libxml / libxslt и используются PHP-реализациейXSLTProcessor (спасибо @Dimitre Novatchev за подтверждение).

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/items">
        <xsl:call-template name="recursivesum">
            <xsl:with-param name="items" select="*" />
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="recursivesum">
        <xsl:param name="items" />
        <xsl:param name="sum" select="0" />
        <xsl:variable name="head" select="$items[1]" />
        <xsl:variable name="tail" select="$items[position()>1]" />
        <xsl:variable name="thissum" select="$head/value * $head/quantity" />
        <xsl:choose>
            <xsl:when test="not($tail)">
                <xsl:value-of select="$sum+$thissum" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="recursivesum">
                    <xsl:with-param name="sum" select="$sum+$thissum" />
                    <xsl:with-param name="items" select="$tail" />
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:transform>
Решение Вопроса

Используйте это выражение XPath 2.0:

Вот преобразование XSLT 2.0 в качестве проверки:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

    <xsl:template match="/">
        <xsl:sequence select=""/>
    </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному документу XML:

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

Выражение XPath оценивается, и результат этой оценки выводится:

8

Объяснение:

В XPath 2.0 для шага определения местоположения допустимо быть

/(expression),

или даж

/someFunction(argumentList)

II. XSLT 1.0 решение:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <xsl:call-template name="sumProducts">
    <xsl:with-param name="pNodes" select="item"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="sumProducts">
   <xsl:param name="pNodes" select="/.."/>
   <xsl:param name="pAccum" select="0"/>

   <xsl:choose>
    <xsl:when test="not($pNodes)">
     <xsl:value-of select="$pAccum"/>
    </xsl:when>
    <xsl:otherwise>
     <xsl:call-template name="sumProducts">
      <xsl:with-param name="pNodes" select="$pNodes[position() >1]"/>
      <xsl:with-param name="pAccum" select=
      "$pAccum + $pNodes[1]/value * $pNodes[1]/quantity"/>
     </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к предоставленному XML-документу (см. выше), снова выдается желаемый, правильный результат:

8

Обратите внимание: Такого рода проблемы легко решить с помощьюFXSL library. Шаблон для вызоваtransform-and-sum .

 Dimitre Novatchev21 мая 2012 г., 15:11
@ hielsnoppe: AFAIK PHP использует libxml / libxslt, который реализует только XPath 1.0 / XSLT 1.0. Невозможно рассчитать требуемое значение только с помощью одного выражения XPath 1.0. Если вы заинтересованы в решении XSLT 1.0, пожалуйста, подтвердите, и я предоставлю его.
 hielsnoppe21 мая 2012 г., 14:39
Как я прокомментировал другой ответ, это выглядит многообещающе для меня, но я не могу заставить его работать с PHP. Это проблема PHP, поддерживающего только XSLT 1.0 / XPath 1.0, или я правильно его не адаптировал? Есть ли подобное решение для версии 1.0?
 hielsnoppe21 мая 2012 г., 15:33
Спасибо за разъяснения по этому поводу! Теперь я сам нашел решение, опубликованное в качестве ответа.
 Dimitre Novatchev22 мая 2012 г., 05:54
@ hielsnoppe: я обновил свой ответ решением XSLT 1.0.

Попробуй это

<xsl:stylesheet version="2.0"xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:sequence select="sum(/items/item/(value * quantity))"/>
    </xsl:template>
</xsl:stylesheet>
 web_bod20 мая 2012 г., 10:58
проблемы с записью вещей из памяти
 hielsnoppe20 мая 2012 г., 10:39
Смотрится многообещающе, но не может заставить его работать с XSLTProcessor PHP. Это проблема PHP или я не правильно ее адаптировал?
 Michael Kay20 мая 2012 г., 10:33
Отсутствует "/". См. Ответ Дмитрия для исправления.

Ваш ответ на вопрос