Какова лучшая практика для рендеринга спрайтов в DirectX 11?

В настоящее время я пытаюсь привыкнуть к DirectX API, и мне интересно, каков обычный подход для рендеринга спрайта в DirectX 11 (например, для клона тетриса).

Есть ли подобный интерфейс какID3DX10Spriteи если нет, то какой будет обычный метод рисования спрайтов в DirectX 11?

Редактировать: вот код HLSL, который работал для меня (вычисление координаты проекции может быть сделано лучше):

struct SpriteData
{
    float2 position;
    float2 size;
    float4 color;
};

struct VSOut
{
    float4 position : SV_POSITION;
    float4 color : COLOR;
};

cbuffer ScreenSize : register(b0)
{
    float2 screenSize;
    float2 padding; // cbuffer must have at least 16 bytes
}

StructuredBuffer<SpriteData> spriteData : register(t0);

float2 GetVertexPosition(uint VID)
{
    [branch] switch(VID)
    {
        case 0:
            return float2(0, 0); 
        case 1:
            return float2(1, 0); 
        case 2:
            return float2(0, 1); 
        default:
            return float2(1, 1);
    }
}

float4 ComputePosition(float2 positionInScreenSpace, float2 size, float2 vertexPosition)
{
    float2 origin = float2(-1, 1);
    float2 vertexPositionInScreenSpace = positionInScreenSpace + (size * vertexPosition);

    return float4(origin.x + (vertexPositionInScreenSpace.x / (screenSize.x / 2)), origin.y - (vertexPositionInScreenSpace.y / (screenSize.y / 2)), 1, 1);
}

VSOut VShader(uint VID : SV_VertexID, uint SIID : SV_InstanceID)
{
    VSOut output;

    output.color = spriteData[SIID].color;
    output.position = ComputePosition(spriteData[SIID].position, spriteData[SIID].size, GetVertexPosition(VID));

    return output;
}

float4 PShader(float4 position : SV_POSITION, float4 color : COLOR) : SV_TARGET
{
    return color;
}

Ответы на вопрос(1)

Решение Вопроса

Нет, не существует эквивалента. Обычным методом было бы нарисовать треугольную полосу, образующую квад.

Вы можете использовать инстансинг, поэтому вам просто нужно обновить буфер с данными спрайта (x, y позиция экрана в пикселях, id текстуры для выборки в массив текстуры, масштабирование, вращение, слой и т. Д.) И использовать шейдеры для рендеринг всех спрайтов в одном вызове.

Вот некоторые лакомые кусочки HLSL:

//--------------------------------------------------------------------------------------
// Shader code for Sprite Rendering
//--------------------------------------------------------------------------------------

struct Sprite {
    float2 position; // x, y world position
    float rotation;
    float scaling;

    float layer; // if you have multiple layers of sprites (e.g. background sprites)
    uint textureId;
};

StructuredBuffer<Sprite> SpritesRO : register( t0 );
Texture2DArray<float4> TextureSlices : register (t1);

cbuffer cbRenderConstants : register( b0 )
{
    matrix g_mViewProjection;
    // other constants
};

struct VSSpriteOut
{
    float3 position : SV_Position;
    uint textureId;
};

//-------------------------------------------------------------------------------------            
// Sprite Vertex Shader
//-------------------------------------------------------------------------------------

VSSpriteOut SpriteVS(uint VID : SV_VertexID, uint SIID : SV_InstanceID)
{
    VSSpriteOut Out = (VSSpriteOut)0;

    // VID is either 0, 1, 2 or 3
    // We can map 0 to position (0,0), 1 to (0,1), 2 to (1,0), 3 to (1,1)

    // We fetch the sprite instance data accord SIID
    Sprite sdata = SpritesRO[SIID];

    // function f computes screen space vertex position
    float3 pos = f (g_mViewProjection, VID, position, rotation, scaling, layer etc)

    Out.position = pos;
    Out.textureId = sdata.textureId;

    return Out;
}

//-------------------------------------------------------------------------------------
// Sprite Pixel Shader
//-------------------------------------------------------------------------------------

float4 SpritePS(VSSpriteOut In) : SV_Target
{
    // use In.textureId to fetch the right texture slice in texture array
    return color;
}
 Stringer08 окт. 2010 г., 14:38
Просмотрите все образцы D3D11 из DXSDK и внимательно посмотрите, как они работают для создания буферов, их связывания, обновления и т. Д.
 Mario Pistrich08 окт. 2010 г., 01:15
Не могли бы вы привести пример короткого кода? Я изо всех сил пытаюсь начать с буфера.
 Mario Pistrich08 окт. 2010 г., 23:28
Вау, спасибо. Это действительно помогло мне начать :)

Ваш ответ на вопрос