Usando o TRichEdit em tempo de execução sem definir um pai

Question

Jul 12, 2010, 01:07 PM

Usando o TRichEdit em tempo de execução sem definir um pai

Eu preciso usar um TRichEdit em tempo de execução para executar a conversão de RTF para texto, conforme discutidoaqui. Consegui fazer isso, mas tive que definir um formulário fictício como pai, caso contrário não consigo preencher o TRichedit.Lines. (Erro: pai está ausente). Eu colo minha função abaixo, alguém pode sugerir uma maneira de evitar definir um pai? Você também pode comentar sobre isso e me dizer se encontra uma ideia com melhor desempenho?

Nota: Preciso de uma string, não de TStrings como saída, é por isso que foi projetada dessa maneira.

function RtfToText(const RTF: string;ReplaceLineFeedWithSpace: Boolean): string;
var
  RTFConverter: TRichEdit;
  MyStringStream: TStringStream;
  i: integer;
  CustomLineFeed: string;

begin
  if ReplaceLineFeedWithSpace then
    CustomLineFeed := ' '
    else
    CustomLineFeed := #13;
  try
    RTFConverter := TRichEdit.Create(nil);
    try
      MyStringStream := TStringStream.Create(RTF);
      RTFConverter.parent := Form4; // this is the part I don't like
      RTFConverter.Lines.LoadFromStream(MyStringStream);
      RTFConverter.PlainText := True;
      for i := 0 to RTFConverter.Lines.Count - 1 do
      begin
        if i < RTFConverter.Lines.Count - 1 then
          Result := Result + RTFConverter.Lines[i] + CustomLineFeed
          else
          Result := Result + RTFConverter.Lines[i];
      end;
    finally
      MyStringStream.Free;
    end;
  finally
    RTFConverter.Free;
  end;

end;

ATUALIZAR: Depois da resposta, atualizei a função e escrevi-a aqui para referência:

function RtfToText(const RTF: string;ReplaceLineFeedWithSpace: Boolean): string;
var
  RTFConverter: TRichEdit;
  MyStringStream: TStringStream;
begin
  RTFConverter := TRichEdit.CreateParented(HWND_MESSAGE);
  try
    MyStringStream := TStringStream.Create(RTF);
    try
      RTFConverter.Lines.LoadFromStream(MyStringStream);
      RTFConverter.PlainText := True;
      RTFConverter.Lines.StrictDelimiter := True;
      if ReplaceLineFeedWithSpace then
        RTFConverter.Lines.Delimiter := ' '
        else
        RTFConverter.Lines.Delimiter := #13;
      Result := RTFConverter.Lines.DelimitedText;
    finally
      MyStringStream.Free;
    end;
  finally
    RTFConverter.Free;
  end;
end;