Как получить элементы по имени в Delphi Chromium Embedded?

Чтобы получить конкретный узел DOM, встроенный в текущий веб-документ, из экземпляра TChromium, используя его идентификатор, вы используете ICefDomDocument.getElementById (). Но как найти элементы по атрибуту NAME? Javascript имеет метод document.getElementsByName (), а TWebBrowser (который оборачивает IE) имеет аналогичный вызов, но я не могу понять, как это сделать с TChromium. Мне нужно найти некоторые элементы DOM, которые имеют атрибуты NAME, но не имеют атрибутов ID. Я искалceflib аппарат и не видел ничего, что бы это делало.

Побочный вопрос. Если у кого-то есть ссылка на TChromium, «рецепты» Стиль сайта или документа я мог бы использовать.

ОБНОВЛЕНИЕ: ожидая ответа, я придумал следующий код для выполнения getElementsbyName (). Мне бы хотелось что-то быстрее, чем сканировать все дерево DOM. Если вы видите что-то не так в коде, дайте мне знать:

type
    TDynamicCefDomNodeArray = array of ICefDomNode;


// Given a Chromium document interface reference and a NAME attribute to search for,
//  return an array of all DOM nodes whose NAME attribute matches the desired.
function getElementsByName(ADocument: ICefDomDocument; theName: string): TDynamicCefDomNodeArray;

    // Get all the elements with a particular NAME attribute value and return
    //  an array of them.
    procedure getElementsByName1(intfParentNode: ICefDomNode; theName: string; var aryResults: TDynamicCefDomNodeArray);
    var
        oldLen: integer;
        intfChildNode: ICefDomNode;
        theNameAttr: string;
    begin
        Result := nil;
        intfChildNode := nil;

        if Assigned(intfParentNode) then
        begin
            // Attributes are case insensitive.
            theNameAttr := intfParentNode.GetElementAttribute('name');

            if AnsiSameText(theNameAttr, theName) then
            begin
                // Name attribute match.  Add it to the results array.
                oldLen := Length(aryResults);
                SetLength(aryResults, oldLen + 1);
                aryResults[oldLen] := intfParentNode;
            end; // if AnsiSameText(intfParentNode.Name, theName) then

            // Does the parent node have children?
            if intfParentNode.HasChildren then
            begin
                intfChildNode := intfParentNode.FirstChild;

                // Scan them.
                while Assigned(intfChildNode) do
                begin
                    getElementsByName1(intfChildNode, theName, aryResults);

                    if Assigned(intfChildNode) then
                        intfChildNode := intfChildNode.NextSibling;
                end;
            end; // if intfParentNode.HasChildren then
        end; // if Assigned(intfParentNode) then
    end;

    // ---------------------------------------------------------------

var
    intfCefDomNode: ICefDomNode;
begin
    intfCefDomNode := nil;
    Result := nil;

    if Assigned(ADocument) then
    begin
        // Check the header.
        intfCefDomNode := ADocument.Document;

        if Assigned(intfCefDomNode) then
        begin
            // Check the parent.
            getElementsByName1(intfCefDomNode, theName, Result);
        end; // if Assigned(intfCefDomNode) then
    end; // if Assigned(ADocoument) then
end;

// ---------------------------------------------------------------
 Jeroen Wiert Pluimers20 мая 2012 г., 11:13
Я не думаю, что было бы разумно смешивать и сопоставлять 10-летнюю технологию с современными технологиями и ожидать, что она станет найденным и стабильным решением. В этом конкретном случае TChromium не поддерживает Delph 6.code.google.com/p/delphichromiumembedded
 Jeroen Wiert Pluimers20 мая 2012 г., 14:17
@TLama, если мой разум служит мне достаточно хорошо, Delphi 7 представил немало исправлений, касающихся упаковки COM-содержимого. Это может быть причиной не поддержки Delphi 6. Я рекомендую Роберту проверить это предположение с командой TChromium.
 TLama20 мая 2012 г., 11:51
@Jeroen, theTChromium Хотя Delphi 6 не поддерживает (пакет для него не существует), но это не означает, что он не может работать там. У меня Delphi 2009, который также не поддерживается, но, глядя на источник, нет ничего, что могло бы помешать его использованию ;-)
 Robert Oschler20 мая 2012 г., 14:55
@TLama - я верю в это. Три единицы Delphi, которые я использую, связанные с Chromium: cef, ceflib, ceffilescheme. Кроме того, у меня есть TChromium, доступный в моей палитре компонентов, и я могу поместить его в форму.

Ответы на вопрос(1)

getElementsByName или MSHTMLgetElementsByName построен вChromium Embedded ни его обертка Delphi в это время. Вы можете решить эту проблему только путем перебора всех элементов DOM, например, создав свой собственный класс посетителей DOM следующим образом:

Пожалуйста, обратите вниманиеVisitDom Процедура асинхронная, поэтому она возвращается немедленно (фактически до того, как посетитель DOM завершитvisit) и он работает со снимком DOM во время его выполнения.

type
  TElementNameVisitor = class(TCefDomVisitorOwn)
  private
    FName: string;
  protected
    procedure visit(const document: ICefDomDocument); override;
  public
    constructor Create(const AName: string); reintroduce;
  end;

procedure ProcessElementsByName(const AFrame: ICefFrame; const AName: string);
var
  Visitor: TElementNameVisitor;
begin
  if Assigned(AFrame) then
  begin
    Visitor := TElementNameVisitor.Create(AName);
    AFrame.VisitDom(Visitor);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  ProcessElementsByName(Chromium1.Browser.MainFrame, 'NameAttributeValue');
end;

{ TDOMElementNameVisitor }

constructor TElementNameVisitor.Create(const AName: string);
begin
  inherited Create;
  FName := AName;
end;

procedure TElementNameVisitor.visit(const document: ICefDomDocument);

  procedure ProcessNode(ANode: ICefDomNode);
  var
    Node: ICefDomNode;
  begin
    if Assigned(ANode) then
    begin
      Node := ANode.FirstChild;
      while Assigned(Node) do
      begin
        if Node.GetElementAttribute('name') = FName then
        begin
          // do what you need with the Node here
          ShowMessage(Node.GetElementAttribute('value'));
        end;
        ProcessNode(Node);
        Node := Node.NextSibling;
      end;
    end;
  end;

begin
  ProcessNode(document.Body);
end;
 20 мая 2012 г., 15:06
Нет, итерацию вы должны выполнить самостоятельно. Разница в использованииVisitDom Метод заключается в том, что он создает копию (снимок) текущего состояния DOM. В моем примереTElementNameVisitor.visit работает с копией документа, а не с самим документом (который можно изменить во время итерации). Я не знаю, быстрее ли это, просто безопаснее.
 Robert Oschler20 мая 2012 г., 15:16
Хорошо спасибо. Это хороший момент.
 Robert Oschler20 мая 2012 г., 14:58
Re: изобретать колесо. Не специально, просто используя то, что я нашел при исследовании использования Chromium с Delphi (см. Мой ответ на ваш комментарий к основному посту).
 20 мая 2012 г., 15:17
Забыл заметить, чтоVisitDom является асинхронным, поэтому я использовал имяProcessElementsByName неgetElementsByName потому что мне пришлось бы ждать, пока посетитель заканчиваетvisit.
 Robert Oschler20 мая 2012 г., 14:59
Итак, я понимаю, что при вызове посещения с потомком TCefDomVisitorOwn реализуется шаблон Visitor? Другими словами, CEF будет применять этот шаблон ко всем узлам в DOM, обрабатывая рекурсивный спуск через дерево узлов? Это очень круто, если да, но я хочу быть абсолютно уверенным, поэтому я прошу подтверждения.

Ваш ответ на вопрос