Динамические библиотеки Fortran, загрузка во время выполнения?

Возможно ли, чтобы программа Fortran загружала библиотеку Fortran во время выполнения? Если да, можно ли изменить функцию и перекомпилировать только библиотеку, чтобы исходно скомпилированная программа вызывала измененную функцию в библиотеке во время выполнения?

Если кто-нибудь может привести минимальный рабочий пример того, как этого можно достичь, это было бы здорово.

 lenzinho04 авг. 2016 г., 02:29
Стив, это на самом деле на OS X.
 Holmz02 авг. 2016 г., 12:57
Нужен ли компоновщику новую библиотеку или он знает, что делать? Вещи отличаются с использованием .a и .so. Я предполагаю, что вы не можете перекомпилировать или не имеете исходного кода для других частей?
 lenzinho04 авг. 2016 г., 03:17
Я пользуюсь ifort
 haraldkl02 авг. 2016 г., 08:08
Вы спрашиваете, как создать динамическую библиотеку?
 paulsm402 авг. 2016 г., 02:52
В: Можно ли заставить программу на Фортране загружать библиотеку на Фортране во время выполнения? A: Конечно. Например, Gnu Fortran поддерживает динамические модули (.so) в Linux.
 Steve Lionel04 авг. 2016 г., 02:57
Ну, dlopen и dlsym могут работать там. А может и нет - OS X - это свой странный мир, который меняет вещи несовместимо с каждым незначительным обновлением. Конечно, в OS X динамические библиотеки называются .dylib. Чей Фортран ты используешь? Вам, вероятно, потребуется использовать ISO_C_BINDING, тип C_FUNPTR и C_F_PROCPOINTER, с TRANSFER для перемещения битов.
 Steve Lionel03 авг. 2016 г., 17:27
Это Linux или Windows? Это возможно на любом из них. В Linux вы вызываете dlopen и dlsym, чтобы получить указатель на подпрограмму, в Windows LoadLibrary и GetProcAddress. Intel Visual Fortran предоставляет полный пример этого для Windows.

Ответы на вопрос(1)

Решение Вопроса

этостраница на rosettacode.org который дает полный пример с деталями и обсудить реализацию на Linux и MACOSэтосообщение на форуме Intel где Стив Лайонел дает несколько советов о том, как сделать динамическую загрузку с помощью ifortэтотСтраница IBM с отличным объяснением динамических библиотек и их использования

Если вы хотите небольшой, легкий для понимания код, продолжайте читать. Несколько дней назад я играл с динамической загрузкой. Мой тестовый код ниже может помочь вам. Однако я работаю в среде Linux, и вам, возможно, придется кое-что адаптировать, чтобы она работала в вашей среде OS X.ссылка на rosettacode.org выше пригодится, чтобы помочь вам.

Вот код для теста динамического lib

[[email protected]:~/test]$cat test.f90

module test
    use, intrinsic :: iso_c_binding
contains
    subroutine t_times2(v_in, v_out) bind(c, name='t_times2')
        integer, intent(in) :: v_in
        integer, intent(out) :: v_out
        !
        v_out=v_in*2
    end subroutine t_times2
    !
    subroutine t_square(v_in, v_out) bind(c, name='t_square')
        integer(c_int), intent(in) :: v_in
        integer(c_int), intent(out) :: v_out
        !
        v_out=v_in**2
    end subroutine t_square
end module test

Составлено как

[[email protected]:~/test]$gfortran -c test.f90
[[email protected]:~/test]$gfortran  -shared -o test.so test.o

Вот тестовая программа

[[email protected]:~/test]$cat example.f90
program example
    use :: iso_c_binding
implicit none

    integer(c_int), parameter :: rtld_lazy=1 ! value extracte from the C header file
    integer(c_int), parameter :: rtld_now=2 ! value extracte from the C header file
    !
    ! interface to linux API
    interface
        function dlopen(filename,mode) bind(c,name="dlopen")
            ! void *dlopen(const char *filename, int mode);
            use iso_c_binding
            implicit none
            type(c_ptr) :: dlopen
            character(c_char), intent(in) :: filename(*)
            integer(c_int), value :: mode
        end function

        function dlsym(handle,name) bind(c,name="dlsym")
            ! void *dlsym(void *handle, const char *name);
            use iso_c_binding
            implicit none
            type(c_funptr) :: dlsym
            type(c_ptr), value :: handle
            character(c_char), intent(in) :: name(*)
        end function

        function dlcl,ose(handle) bind(c,name="dlclose")
            ! int dlclose(void *handle);
            use iso_c_binding
            implicit none
            integer(c_int) :: dlclose
            type(c_ptr), value :: handle
        end function
    end interface

    ! Define interface of call-back routine.
    abstract interface
        subroutine called_proc (i, i2) bind(c)
            use, intrinsic :: iso_c_binding
            integer(c_int), intent(in) :: i
            integer(c_int), intent(out) :: i2
        end subroutine called_proc
    end interface

    ! testing the dynamic loading
    integer i, i2
    type(c_funptr) :: proc_addr
    type(c_ptr) :: handle
    character(256) :: pName, lName

    procedure(called_proc), bind(c), pointer :: proc
    !
    i = 15

    handle=dlopen("./test.so"//c_null_char, RTLD_LAZY)
    if (.not. c_associated(handle))then
        print*, 'Unable to load DLL ./test.so'
        stop
    end if
    !
    proc_addr=dlsym(handle, "t_times2"//c_null_char)
    if (.not. c_associated(proc_addr))then
        write(*,*) 'Unable to load the procedure t_times2'
        stop
    end if
    call c_f_procpointer( proc_addr, proc )
    call proc(i,i2)
    write(*,*) "t_times2, i2=", i2
    !
    proc_addr=dlsym( handle, "t_square"//c_null_char )
    if ( .not. c_associated(proc_addr) )then
        write(*,*)'Unable to load the procedure t_square'
        stop
    end if
    call c_f_procpointer(proc_addr, proc)
    call proc(i,i2)
    write(*,*) "t_square, i2=", i2
contains
end program example

Скомпилировано и работает как:

[[email protected]:~/test]$gfortran -o example example.f90 -ldl
[[email protected]:~/test]$./example
t_times2, i2=          30
t_square, i2=         225
[[email protected]:~/test]$

Ваш ответ на вопрос