Доступ к функции внутри загруженного файла .swf?

Есть ли способ вызвать функцию внутри загруженного SWF-файла?

По сути, у меня есть файл .swf (A), который загружает другой файл .swf (B) ... Я просто хотел бы обработать B, как если бы это был любой другой экземпляр, добавленный в мой класс .swf "A" ...

Необходимо переписать "Loader" с именем вашего класса файлов .swf:

Загруженный класс .swf:

package src {
import flash.display.MovieClip;

public class LoadedSWF extends MovieClip     {
    public function LoadedSWF() {
    }

    public function helloWorld():void
    {
        trace("hello world from loaded swf!");
    }
}
}

Основной класс:

package src {
import flash.display.Loader;
import flash.net.URLRequest;
import flash.display.MovieClip;
import flash.events.Event;

public class Main extends MovieClip {

    private var loader:Loader;

    public function Main() {
        loadSWF("LoadedSWF.swf")
    }

    private function loadSWF(url:String):void {
        var urlRequest:URLRequest = new URLRequest(url);
        loader = new Loader();
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaded, false, 0, true);
        loader.load(urlRequest);
        addChild(loader);

    }

    private function onLoaded(e:Event):void {
        var target:LoadedSWF = e.currentTarget.loader.content as LoadedSWF;
        trace(target);
        target.helloWorld();

        addChild(target);
    }
}

}

Ответы на вопрос(2)

Ваш ответ на вопрос