Estou tentando criar matrizes heterogêneas que contêm variáveis de tipos diferentes, por exemplo,[ 1.0, 7, "hi" ]. Eu tentei incluirclass(*) outype(*) no construtor do array (veja o final do código a seguir), mas o gfortran5.2 simplesmente o considera um erro de sintaxe. Existe alguma maneira de criar essa matriz com o construtor da matriz ou é necessário usar uma abordagem diferente (por exemplo, definir um tipo que contenha cada elemento separadamente)?

Mais detalhes:

O código a seguir é um exemplo do motivo pelo qual desejo criar uma matriz desse tipo. ochecktype_multi rotina recebe vários argumentos com ooptional palavra-chave, mas essa abordagem é claramente limitada por causa do número fixo de argumentos. Para permitir um número arbitrário de argumentos, tentei ochecktype_array rotina, mas não parece possível passar uma matriz com tipos diferentes ...caso pode ser uma sub-rotina para imprimir um número variável de argumentos com vários tipos.

module mymod
    implicit none
contains

    subroutine checktype ( x )
        class(*) :: x

        select type ( x )
            type is ( integer )      ; print *, "int    : ", x
            type is ( real )         ; print *, "real   : ", x
            type is ( character(*) ) ; print *, "string : ", x
        endselect
    end subroutine

    subroutine checktype_multi ( x1, x2, x3 )
        class(*), optional :: x1, x2, x3

        print *
        if ( present( x1 ) ) call checktype ( x1 )
        if ( present( x2 ) ) call checktype ( x2 )
        if ( present( x3 ) ) call checktype ( x3 )
    end subroutine

    subroutine checktype_array ( a )
        class(*) :: a(:)
        integer :: k

        print *
        do k = 1, size( a )
            call checktype ( a( k ) )
        enddo
    end subroutine

end module

program main
    use mymod

    call checktype_multi ( 1.0 )
    call checktype_multi ( 1.0, 7 )
    call checktype_multi ( 1.0, 7, "hi" )

    ! call checktype_array ( [ 1.0, 7, "hi" ] )  !! error (this is to be expected)

    !>>> Here is the problem.
    ! call checktype_array ( [ type(*)  :: 1.0, 7, "hi" ] )  !! this is also an error
    ! call checktype_array ( [ class(*) :: 1.0, 7, "hi" ] )  !! this too
end program