QML: Как отказаться от действия отбрасывания

у меня есть такойDropArea и два элемента. я хочуDropArea отклонить событие сброса, еслиDropArea Уже один элемент может быть удален, другой элемент не может быть добавлен, если только первый элемент не вышел.

DropArea {
    property bool dropped: false

    onDropped: {
        drop.accepted = !dropped;
        dropped = true;
    }
    onExited: dropped = false
}

Но выглядит какdrop.accepted не работает, кстати, чтобы получить объекты были сброшены вDropArea

 BaCaRoZzo28 июн. 2016 г., 13:52
Какая версия Qt?

Ответы на вопрос(2)

использованиеdrop.accept() вместо. Вышесказанное можно сделать следующим образом:

property bool containsItem: false
DropArea {
    id: dropArea
    anchors.fill: parent
    onDropped: {
        if(containsItem)
            drop.accept(Qt.IgnoreAction)
        else
            drop.accept()

        containsItem = true;
    }
}

Также не используйтеdropped свойство, поскольку оно уже является вложенным свойством внутриonDropped обработчик события.

Изменить: еслиrect это элемент, который нужно перетащить и затем отбросить:

Rectangle {
    id: rect
    width: 40; height: 40
    color: "red"

    Drag.active: dragArea.drag.active
    Drag.hotSpot.x: 20
    Drag.hotSpot.y: 20

    MouseArea {
        id: dragArea
        anchors.fill: parent
        drag.target: parent
        onReleased: if (rect.Drag.drop() !== Qt.IgnoreAction) {
                        console.log("Accepted!");
                    } else {
                        console.log("Rejected!");
                    }
    }
}
 astre28 июн. 2016 г., 09:53
Действие игнорировать или принять может быть обработано внутриonReleased обработчик перетаскиваемых объектовMouseArea
 Jiu28 июн. 2016 г., 09:49
Спасибо ноdrop.accept(Qt.IgnoreAction) все еще не работает. Как это:onDropped: { drop.accept(Qt.IgnoreAction) }
Решение Вопроса

Вы должны контролировать, должен ли предмет быть уронен или нетonReleased, проверяяdropped имущество.

Полный пример:

import QtQuick 2.5
import QtQuick.Window 2.2
import QtQuick.Controls 1.4

Window {
    id: win
    visible: true
    width: 800
    height: 600
    title: qsTr("Hello World")

    Repeater {
        model: 10
        Rectangle {
            id: rect
            width: 50
            height: 50
            z: mouseArea.drag.active ||  mouseArea.pressed ? 2 : 1
            color: Qt.rgba(Math.random(), Math.random(), Math.random(), 1)
            x: Math.random() * (win.width / 2 - 100)
            y: Math.random() * (win.height - 100)
            property point beginDrag
            property bool caught: false
            border { width:2; color: "white" }
            radius: 5
            Drag.active: mouseArea.drag.active

            Text {
                anchors.centerIn: parent
                text: index
                color: "white"
            }
            MouseArea {
                id: mouseArea
                anchors.fill: parent
                drag.target: parent
                onPressed: {
                    rect.beginDrag = Qt.point(rect.x, rect.y);
                }
                onReleased: {
                    if(!rect.caught || dragTarget.dropped) {
                        backAnimX.from = rect.x;
                        backAnimX.to = beginDrag.x;
                        backAnimY.from = rect.y;
                        backAnimY.to = beginDrag.y;
                        backAnim.start()
                    }

                    parent.Drag.drop()

                    console.log("MouseArea - containsDrag " + dragTarget.dropped)
                }

            }
            ParallelAnimation {
                id: backAnim
                SpringAnimation { id: backAnimX; target: rect; property: "x";
                                  duration: 500; spring: 2; damping: 0.2 }
                SpringAnimation { id: backAnimY; target: rect; property: "y";
                                  duration: 500; spring: 2; damping: 0.2 }
            }
        }
    }

    Rectangle {
        anchors {
            top: parent.top
            right:  parent.right
            bottom:  parent.bottom
        }
        width: parent.width / 2
        color: "gold"
        DropArea {
            id: dragTarget
            anchors.fill: parent

            property bool dropped: false

            onEntered: {
                console.log("onEntered " + containsDrag)
                drag.source.caught = true;
            }
            onExited: {
                console.log("onExited " + containsDrag)
                dropped = false;
            }
            onDropped:
            {
                console.log("onDropped");
                dropped = true;
            }
        }
    }
}

Ваш ответ на вопрос