Ich benutze dieCheckTokenMembership Windows-API zum Überprüfen, ob der Benutzer ein Administrator ist.

Hier ist der Code:

Option Explicit

Private Const SECURITY_BUILTIN_DOMAIN_RID       As Long = &H20
Private Const DOMAIN_ALIAS_RID_ADMINS           As Long = &H220

Private Declare Function AllocateAndInitializeSid Lib "advapi32.dll" (pIdentifierAuthority As Any, ByVal nSubAuthorityCount As Byte, ByVal nSubAuthority0 As Long, ByVal nSubAuthority1 As Long, ByVal nSubAuthority2 As Long, ByVal nSubAuthority3 As Long, ByVal nSubAuthority4 As Long, ByVal nSubAuthority5 As Long, ByVal nSubAuthority6 As Long, ByVal nSubAuthority7 As Long, lpPSid As Long) As Long
Private Declare Sub FreeSid Lib "advapi32.dll" (ByVal pSid As Long)
Private Declare Function CheckTokenMembership Lib "advapi32.dll" (ByVal hToken As Long, ByVal pSidToCheck As Long, pbIsMember As Long) As Long

Private Type SID_IDENTIFIER_AUTHORITY
    Value(0 To 5)            As Byte
End Type

Private Function pvIsAdmin() As Boolean
    Dim uAuthNt         As SID_IDENTIFIER_AUTHORITY
    Dim pSidAdmins      As Long
    Dim lResult         As Long

    uAuthNt.Value(5) = 5
    If AllocateAndInitializeSid(uAuthNt, 2, SECURITY_BUILTIN_DOMAIN_RID, DOMAIN_ALIAS_RID_ADMINS, 0, 0, 0, 0, 0, 0, pSidAdmins) <> 0 Then
        If CheckTokenMembership(0, pSidAdmins, lResult) <> 0 Then
            pvIsAdmin = (lResult <> 0)
        End If
        Call FreeSid(pSidAdmins)
    End If
End Function

Das Problem ist, dass unter Windows 7 und Windows 2008 SP2 der Aufruf von FreeSID zum Absturz der App führt. Der Absturz ist zeitweise.

Hat jemand dieses Problem festgestellt?

Vielen Dank!

BEARBEITEN:

Ich habe gerade meinen Code überprüft und festgestellt, dass ich FreeSID als solches deklariert habe:

Private Declare Sub FreeSid Lib "advapi32.dll" (pSid As Long)

Im Vergleich zum obigen Code ist der Parameter pSid hier nicht als ByVal gekennzeichnet. Ich habe das ByVal-Flag hinzugefügt und das Problem ist nicht mehr vorhanden. Irgendwie bin ich nicht davon überzeugt, dass dies das Problem behoben hat. Kann das evtl. das Problem behoben haben?